home *** CD-ROM | disk | FTP | other *** search
/ Network CD 1 / Network CD.iso / others / emit / emit20.lzh / aprintf.asm next >
Assembly Source File  |  1988-01-30  |  3KB  |  98 lines
  1. * ------------------------------------------------------------------------- *
  2. * Aprintf.asm
  3. * Copyright Justin V. McCormick 1988
  4. * ------------------------------------------------------------------------- *
  5.     TTL    aprintf.asm
  6.  
  7.     SECTION    aprintf,CODE
  8.  
  9.     NOLIST
  10.     include "macros.i"
  11.  
  12. ;    include "libraries/dos_lib.i"
  13. ;    include    "exec/exec_lib.i"
  14.  
  15. * Equates replacing above files includes
  16. _LVORawDoFmt    EQU    $FFFFFDF6
  17. _LVOWrite    EQU    $FFFFFFD0
  18.  
  19.     LIST
  20.  
  21. * Externals
  22.     XREF    _cliout        ;CLI standard output filehandle, LONG
  23.     XREF    _DOSBase    ;Pointer to DOSBase, LONG
  24. * ------------------------------------------------------------------------- *
  25. * void aprintf(formatstring, args)
  26. *   char *formatstring;
  27. *   char **args;
  28. * 
  29. * Synopsis: Given formatstring and args to format, prints output to current
  30. * terminal output channel, globally defined as _cliout, where:
  31. * 
  32. *   LONG cliout;
  33. *   cliout = Output();
  34. *   
  35. * No error checking is performed for cliout pointing to a valid filehandle,
  36. * i.e., you must initialize cliout before calling aprintf().  _DOSBase must
  37. * be initialized as:
  38. *   struct DOSBase *DOSBase;
  39. *   DOSBase = (struct DOSBase *)OpenLibrary("dos.library", 33L);
  40. * ------------------------------------------------------------------------- *
  41.     XDEF    _aprintf
  42. _aprintf:
  43.     link    a5,#-512        ;Allocate 512 bytes on stack
  44.     movem.l    d0/d1/a0-a3,-(sp)    ;Save everything we might clobber
  45.  
  46. * Call format function to convert fmtstring and args to buffer on the stack
  47.     movea.l    8(a5),a0        ;Grab format string
  48.     lea    12(a5),a1        ;Grab EA of arguments
  49.     lea    kput1(pc),a2        ;Grab EA of output subroutine
  50.     lea    -512(a5),a3        ;Grab EA of temp workspace
  51.     SYS    RawDoFmt,4        ;Format it into workspace
  52.  
  53. * Calculate length of resulting string, output to console CLI
  54.     lea    -512(a5),a0        ;a0 = Start of buffer
  55.     move.l    a0,d2            ;Copy for output
  56.     bsr.s    astrlen            ;Calculate string length
  57.     move.l    d0,d3            ;length of string
  58.     move.l    _cliout,d1        ;Filehandle
  59.     SYS    Write,_DOSBase        ;Dump the string to stdout
  60.     
  61.     movem.l    (sp)+,d0/d1/a0-a3    ;Restore registers
  62.     unlk    a5            ;And stack frame
  63.     rts
  64.  
  65. * ------------------------------------------------------------------------- *
  66. * RawDoFmt() output routine for aprintf, called for each formatted char.
  67. * Takes byte in d0 and puts in buffer pointed to by a3, then increments a3.
  68. * ------------------------------------------------------------------------- *
  69.     XDEF    kput1
  70. kput1:
  71.     move.b    d0,(a3)+
  72.     rts
  73.  
  74. * ------------------------------------------------------------------------- *
  75. * LONG astrlen(string)
  76. *  d0            a0
  77. *   char *string;
  78. *
  79. * Synopsis: Calculate length of null-byte terminated string.
  80. * 
  81. * Modifies: d0 = length of string, a0 = next byte address after zero byte.
  82. * ------------------------------------------------------------------------- *
  83.     XDEF    astrlen
  84. astrlen:
  85.     moveq    #0,d0        ;Clear count
  86. 1$
  87.     tst.b    (a0)+        ;Test a byte for zero-ness
  88.      beq.s    2$        ;Found it! return length
  89.     
  90.     addq.w    #1,d0        ;Otherwise bump count
  91.      bra.s    1$        ;Check next byte
  92.  
  93. 2$
  94.     rts
  95.  
  96. * ------------------------------------------------------------------------- *
  97.     END
  98.